10 DIMD$(23),TS(5),W$(20),L1(12),L2(12)
20 D$(0)="":FORX=1TO23:D$(X)=D$(X-1)+"":NEXT:C=54272:FORX=1TO160:READW$:NEXT
30 FORX=1TO12:READL1(X):NEXT:PRINT"[147]":POKE53280,0:POKE53281,0:POKE646,1
40 PRINTD$(12)TAB(17)"WHATZIT":FORX=15TO1STEP-1:POKE646,X
50 PRINTD$(10)TAB(15)"           ":FORY=1TO3:PRINTTAB(15)" "TAB(25)" ":NEXT
60 PRINTTAB(15)"           ":PRINTD$(8)TAB(13)"               "
70 FORY=1TO7:PRINTTAB(13)" "TAB(27)" ":NEXT:PRINTTAB(13)"               "
80 PRINTD$(6)TAB(11)"                   ":FORY=1TO11
90 PRINTTAB(11)" "TAB(29)" ":NEXT:PRINTTAB(11)"                   "
100 PRINTD$(4)TAB(9)"                       ":FORY=1TO15
110 PRINTTAB(9)" "TAB(31)" ":NEXT:PRINTTAB(9)"                       ":NEXT
120 FORX=CTOC+23:POKEX,0:NEXT:POKEC+24,15:POKEC+5,10:POKEC+6,10
130 READH:IFH=0THEN160
140 READL:POKEC,L:POKEC+1,H:POKEC+4,17:FORX=1TO100:NEXT:POKEC+4,16
150 FORX=1TO75:NEXT:GOTO130
160 PRINT"[147]":POKE53280,2:POKE53281,3:POKE646,6:PRINTD$(2)TAB(6)"I'M HUNGRY"
170 PRINTTAB(6)"MUSIC MAKERS":PRINTTAB(6)"PEOPLE PARTS"
180 PRINTTAB(6)"PRETTY PETALS":PRINTTAB(6)"HOME SWEET HOME"
190 PRINTTAB(6)"HOW'S THE WEATHER?":PRINTTAB(6)"ALL WORK AND NO PLAY"
200 PRINTTAB(6)"TWO LEGS, FOUR LEGS, NO LEGS":POKE646,2
210 PRINTTAB(6)"MOVE CURSOR WITH JOYSTICK...."
220 PRINTTAB(7)"PRESS FIRE BUTTON TO SELECT":OP=1108:POKEOP,160:POKEOP+C,1
230 FORX=1TO100:NEXT:IF(PEEK(56320)AND16)=0THEN290
240 J=15-(PEEK(56320)AND15):IFJ=1THENDI=-80:GOTO270
250 IFJ=2THENDI=80:GOTO270
260 GOTO230
270 NP=OP+DI:IFNP<1108ORNP>1668THEN230
280 POKENP+C,1:POKEOP,32:POKENP,160:POKEOP+C,3:OP=NP:GOTO230
290 RESTORE:CA=(OP-1028)/80:ONCAGOSUB300,310,320,330,340,350,360,370:GOTO380
300 RETURN
310 FORX=1TO20:READW$:NEXT:RETURN
320 FORX=1TO40:READW$:NEXT:RETURN
330 FORX=1TO60:READW$:NEXT:RETURN
340 FORX=1TO80:READW$:NEXT:RETURN
350 FORX=1TO100:READW$:NEXT:RETURN
360 FORX=1TO120:READW$:NEXT:RETURN
370 FORX=1TO140:READW$:NEXT:RETURN
380 FORX=1TO20:READW$(X):NEXT
390 PRINT"[147]":POKE53280,0:POKE53281,0:POKE646,1
400 PRINTD$(18)TAB(4)"WORD"TAB(17)"SCORE"TAB(24)"BONUS"TAB(31)"TOTAL"
410 WC=0:TC=0:CU=18
420 WC=WC+1:IFWC>5THEN800
430 TC=TC+2:POKE646,TC:PRINTD$(2)TAB(11)"                 ":FORX=1TO3
440 PRINTTAB(11)"     ":PRINTTAB(11)" "TAB(27)" "
450 PRINTTAB(11)"     ":PRINTTAB(11)"             ":NEXT
460 PRINTTAB(11)"[145]                 ":POKE646,13
470 FORX=1TO12:L2(X)=L1(X):NEXT:LP=0:WP$=""
480 WN=INT(RND(1)*20)+1:IFW$(WN)=""THEN480
490 LP=LP+1:IFLP>LEN(W$(WN))THEN520
500 X=INT(RND(1)*12)+1:IFL2(X)=0THEN500
510 POKEL2(X),ASC(MID$(W$(WN),LP,1))-64:POKEL2(X)+C,14:L2(X)=0:GOTO490
520 X=INT(RND(1)*12)+1:IFL2(X)=0THEN520
530 OP=L2(X):POKEOP,42:POKEOP+C,7:TI$="000000"
540 FORX=1TO60:NEXT:IF(PEEK(56320)AND16)=0THEN620
550 J=15-(PEEK(56320)AND15):IFJ=1THENDI=-40:GOTO600
560 IFJ=2THENDI=40:GOTO600
570 IFJ=4THENDI=-1:GOTO600
580 IFJ=8THENDI=1:GOTO600
590 GOTO540
600 NP=OP+DI:IFPEEK(NP)<>32THEN540
610 POKENP+C,7:POKEOP,32:POKENP,42:POKEOP+C,0:OP=NP:GOTO540
620 IFPEEK(OP-40)>26THEN540
630 WP$=WP$+CHR$((PEEK(OP-40))+64):PRINTD$(1)TAB(11)WP$:POKEOP-40,32
640 POKEOP-40+C,0:IFLEN(WP$)<>LEN(W$(WN))THEN550
650 T=VAL(TI$):POKE646,10:POKEOP,32:POKEOP+C,0:IFWP$=W$(WN)THEN680
660 FORX=CTOC+24:POKEX,0:NEXT:FORX=1TO10:POKEC+24,15:FORQ=1TO3:NEXT
670 POKEC+24,0:FORQ=1TO3:NEXT:NEXT:GOTO690
680 POKEC+24,15:POKEC,10:POKEC+1,100:POKEC+5,9:POKEC+6,9:POKEC+4,17:POKEC+4,16
690 CU=CU+1:PRINTD$(CU)TAB(4)W$(WN);:SC=0:IFWP$=W$(WN)THENSC=LEN(WP$)
700 PRINTTAB(19);:IFSC<10THENPRINT" ";
710 PRINTSC;TAB(26);:BO=0:IFT<30THENBO=30-T
720 IFSC=0THENBO=0
730 IFBO<10THENPRINT" ";
740 PRINTBO;TAB(33);:TS(WC)=SC+BO:IFTS(WC)<10THENPRINT" ";
750 PRINTTS(WC):POKE646,15
760 PRINTD$(16)TAB(11)"PRESS FIRE BUTTON":FORX=1TO50:NEXT
770 PRINTD$(16)TAB(11)"                 ":FORX=1TO30:NEXT
780 IF(PEEK(56320)AND16)=16THEN760
790 PRINTD$(1)TAB(11)"            ":W$(WN)="":GOTO420
800 PRINTD$(23):FORX=1TO15:PRINT:NEXT:POKE646,8
810 PRINTD$(12)TAB(16)"GAME OVER":GT=0:FORX=1TO5:GT=GT+TS(X):NEXT
820 PRINTTAB(13)"GRAND TOTAL"GT:IFGT>HSTHENHS=GT
830 POKE646,3:PRINTTAB(13)"HIGH SCORE"HS:POKE646,12
840 PRINTTAB(11)"PLAY AGAIN? YES/NO":OP=1807:POKEOP,30:POKEOP+C,3
850 POKE646,13:PRINTTAB(10)"MOVE ";:POKE646,3:PRINT"^";:POKE646,13
860 PRINT" WITH JOYSTICK":PRINTTAB(7)"PRESS FIRE BUTTON TO SELECT"
870 IF(PEEK(56320)AND16)=0THEN930
880 J=15-(PEEK(56320)AND15):IFJ=4THENDI=-4:GOTO910
890 IFJ=8THENDI=4:GOTO910
900 GOTO870
910 NP=OP+DI:IFNP<1807ORNP>1811THEN870
920 POKENP+C,3:POKEOP,32:POKENP,30:POKEOP+C,0:OP=NP:GOTO870
930 IFOP=1807THEN160
940 SYS64759
950 DATAHAMBURGER,PIZZA,CABBAGE,CARROT,SPAGHETTI,STRAWBERRY,PINEAPPLE,RAISIN
960 DATACHEESE,EGGPLANT,POTATO,BANANA,CUCUMBER,YOGURT,BOLOGNA,MARSHMALLOW,CHILI
970 DATAONION,SQUASH,RHUBARB,GUITAR,BANJO,VIOLIN,DRUM,SAXOPHONE,TRUMPET
980 DATACLARINET,PIANO,ACCORDION,HARMONICA,HARP,MANDOLIN,FLUTE,XYLOPHONE,ORGAN
990 DATACELLO,TUBA,TROMBONE,CYMBAL,TAMBOURINE,SHOULDER,ANKLE,HEART,STOMACH
1000 DATAKIDNEY,CORNEA,LIVER,SPLEEN,BRAIN,ELBOW,FINGER,TOOTH,AORTA,KNUCKLE
1010 DATAWRIST,LUNG,INTESTINE,FOOT,NECK,TONGUE,ORCHID,PETUNIA,ZINNIA,MARIGOLD
1020 DATAASTER,ROSE,PEONY,TULIP,CROCUS,AMARYLLIS,HYACINTH,IRIS,PANSY,GLOXINIA
1030 DATABEGONIA,SNAPDRAGON,GERANIUM,DAISY,VIOLET,LILY,STEREO,CARPET
1040 DATASILVERWARE,TELEPHONE,TELEVISION,SHELF,TOASTER,CURTAIN,CLOCK,CABINET
1050 DATACHAIR,STOVE,BLANKET,PILLOW,TABLE,LAMP,CALENDAR,CLOTHING,THERMOSTAT
1060 DATABROOM,TORNADO,LIGHTNING,THUNDER,SNOW,SLEET,RAINBOW,HURRICANE,HUMIDITY
1070 DATATEMPERATURE,BAROMETER,FORECAST,CLOUD,FLOOD,HAIL,FRONT,DROUGHT,BLIZZARD
1080 DATAWIND,WARNING,FROST,ATTORNEY,SURGEON,BANKER,ARTIST,WRITER,CARPENTER
1090 DATAENGINEER,REPORTER,ARCHITECT,LIBRARIAN,NURSE,CHEF,POLITICIAN,TEACHER
1100 DATAPLUMBER,JANITOR,FARMER,CLERK,ATHLETE,ELECTRICIAN,TURTLE,COUGAR
1110 DATARATTLESNAKE,SALMON,OSTRICH,PEACOCK,ZEBRA,SKUNK,BUFFALO,KANGAROO,LIZARD
1120 DATAHUMMINGBIRD,CHIMPANZEE,ANTELOPE,SHEEP,DOLPHIN,SQUIRREL,RACCOON,GOPHER
1130 DATAWOODPECKER,1197,1201,1205,1209,1357,1361,1365,1369,1517,1521,1525,1529
1140 DATA22,96,44,193,89,131,25,30,50,60,100,121,28,49,56,99,112,199,0,0